subroutine plate (X,Y,Z,ID,NUMNP)

Cf77*****************************************************************************
C   
C   Programmbeschreibung:
C   --------------------
C   Routine f�uer ein 4-Knoten isoparametrisches Plattenelement. 
C   Das Element ist schubweich und besitzt 3 FHG je Knoten.
C
C   Einen Wegfreiheitsgrad in Z-Achsen Richtung: Im Bild durch A gekennzeichnet 
C   Einen Drehfreiheitsgrad um die X-Achse: Im Bild durch -->> gekennzeichnet
C   Einen Drehfreiheitsgrad um die Y-Achse: Im Bild nicht gekennzeichnet
C
C        
C                         A            A
C                         |            |
C                         o-->>--------o-->>
C                        /4           /3
C                       /            /
C                    A /          A /
C                    |/           |/
C                    o-->>--------o-->>
C                    1            2
C              
C              Z  Y
C              | /
C              |/  
C              o---- X
C    
C   Bild: Knoten- und Freiheitsgradanordnung 
C
C                         
C   Eingangsvaribalen:
C
C    Name          |    Beschreibung
C   -----------------------------------------------------------------------------
C    X             |X-Koordinaten der Knotenpunkte 
C    Y             |Y-Koordinaten der Knotenpunkte
C    Z             |Z-Koordinaten der Knotenpunkte
C    ID            |IDENTITY-Feld
C    NUMNP         |Anzahl der Knotenpunkte (NUMber of Nodal Points) 
C
C
C   Ausgangsvariablen:
C
C    Name          |    Beschreibung
C   -----------------------------------------------------------------------------
C    CHI           | konstante Terme der Jacobi-Matrix
C    LM            | Location-Matrix
C    S             | Elementsteifigkeitsmatrix
C    ST            | Kraft-Verschiebungsmatrix
C    E             | Elastizitätsmodul 
C    Q             | Querdehnzahl
C               
C   Interne Variablen:  nume
C
C   Laufvariablen: mm, i,   
C   
C   rufendes Programm: ELSTF
C                  
C   subroutine: PLATES, CALBAN
C
C   common-blocks: /ELPAR/NPAR,NNNN,NELTYP,N1,N2,N3,N4,N5,MTOT,NEQ
C                   S,ST,LM,IOFIL,NT1,NT2,NT3,NIN,NOT 
C
C   Literatur: Matzenmiller, Hartmann, Hughes.......
C     
C   Erstellt von: Mark Fiolka
C
C   Datum : 19.12.2001
C
C   Gae„ndert: 17.01.2002
C   
C
C ******************************************************************************
      INTEGER m,ni,nj,nk,nl,nd,ns
      REAL E,Q,CHI
      dimension x(1),Y(1),Z(1),ID(NUMNP,6),CHI(10)
      COMMON /ELPAR/ NPAR(14),NNNNN,MBAND,NELTYP,N1,N2,N3,N4,N5,MTOT,NEQ
      COMMON S(12,12),ST(5,12),LM(12) 
      COMMON /IOFIL/ NT1,NT2,NT3,NIN,NOT
      nd=12
      ns=5
      NUME=NPAR(2)
      WRITE (not,2000) NUME
      WRITE(*,*) '  ---> SR Plate'

! *** 
      do 500 mm=1,nume
         read (nin,1001) m,ni,nj,nk,nl,E,Q
         write (not,2001) m,ni,nj,nk,nl,E,Q
            
! *** berechnen der konstanten Terme der Koeffizienten der Jacobi-Matrix
!
         CHI(1) = -X(ni)+X(nj)+X(nk)-X(nl)
         CHI(2) = -X(ni)-X(nj)+X(nk)+X(nl)
         CHI(3) = -Y(ni)+Y(nj)+Y(nk)-Y(nl)
         CHI(4) = -Y(ni)-Y(nj)+Y(nk)+Y(nl)
         CHI(5) =  X(ni)-X(nj)+X(nk)-X(nl)
         CHI(6) =  Y(ni)-Y(nj)+Y(nk)-Y(nl)
         do 100 i=1,6
  100       CHI(i) = CHI(i)/4.0
         
         
!
! *** Aufruf der Subr. PLATES zur Berechnung der Elementsteifigkeitsmatrix
!
         call plates (CHI,E,Q,S,ST,nd,ns)

         
! 
! *** zuordnen der Elementfreiheitsgrade zu den Strukturfreiheitsgraden
!        
         
         
         LM(1) = ID(ni,3)
         LM(2) = ID(ni,4)
         LM(3) = ID(ni,5)
         LM(4) = ID(nj,3)
         LM(5) = ID(nj,4)
         LM(6) = ID(nj,5)
         LM(7) = ID(nk,3)
         LM(8) = ID(nk,4)
         LM(9) = ID(nk,5)
         LM(10)= ID(nl,3)
         LM(11)= ID(nl,4)
         LM(12)= ID(nl,5)
        
       CALL CALBAN(ns,nd,LM,S,ST,MBAND)
        WRITE (NT2,*) (LM(I),I=1,nd),((ST(I,J),J=1,nd),I=1,ns)
  500   CONTINUE
      RETURN
 1001 FORMAT (5I5,2F15.0) 
 2000 FORMAT (// I4, 13HPLATE MEMBERS/
     1 ,7H NUMBER,6X,1HI,6X,1HJ,6X,1HK,6X,1HL,14X,1HE,13X,2HNU)
 2001 FORMAT (5I7,2F15.3)
      END